[Gretl-users] Estimating ARMA model with GARCH errors

[Riccardo Jack Lucchetti]

On Thu, June 8, 2006 08:29, Riccardo Jack Lucchetti"" wrote:
>
> at present, the only way you have in gretl to estimate an arma model with
> garch variance is to use the "mle" command. Section 10.4 in the manual reports
> an example with a garch(1,1) model. A simple adaptation of that example
> follows: ...

A slight enhancement of the above, which uses arma to initialise some of the
parameters (note: I am running this on CVS. It should run OK on the windows
snapshot, and *might* run on 1.5.1):

open djclose
series y = 100*ldiff(djclose)

arma 1 1 ; y --conditional

scalar mu = $coeff(const)
scalar alpha = 0.1
scalar beta = 0.8
scalar phi = $coeff(phi_1)
scalar theta = $coeff(theta_1)
scalar omega = $sigma^2/(1-alpha-beta)

mle ll = -0.5*(log(h) + (e^2)/h)
series e = 0
series e = y - mu - phi*y(-1) - theta*e(-1)
series h = var(y)
series h = omega + alpha*(e(-1))^2 + beta*h(-1)
params mu phi theta omega alpha beta
end mle


Hope this helps,


Riccardo "Jack" Lucchetti
Dipartimento di Economia
Facoltà di Economia "G. Fuà"
Ancona